|
突破划线主图+突破选股公式源码 真假突破的判断，实战方向的选择
实盘操作中，往往因为庄家的假突破跟进去被深深地套住。泊砂本着规避假突破被套的思路，编写了此指标公式。
泊砂在编写时可能用到论坛上某些老师的源码，在此深表感谢！
此指标的特点：（划线有未来，怕者莫用）
1、中线回归趋势判断的自动划线；
2、短线支撑和压力判断的自动划线；
3、模拟三角形突破和箱体突破的自动划线；
4、薛斯通道背景和持股持币的辅助参考；
5、指标中对突破介入，有明确的文字提示；
6、无量的反抽往往是下跌中继的陷阱；在突破选股公式中，特别强调量能放大和趋势成立的选股思路。
源码：
1. 主图公式
{泊砂突破划线（主图公式）.划线有未来}
{箱体 }
N:=13;
BC:=(H*0.382+L*0.618+O*0.382+C*0.618)/2;
LJ:=IF(INDEXC=C,BC,(BC+AMOUNT/(V*100))/2),COLORGRAY;
HT:=REF((HHV(LJ,N*0.691)+HHV(LJ,N)+HHV(LJ,N*1.309))/3,1),LINETHICK,COLORRED;
LT:=REF((LLV(LJ,N*0.691)+LLV(LJ,N)+LLV(LJ,N*1.309))/3,1),LINETHICK,COLORGREEN;
ZT:=(HT+LT)/2,LINETHICK,COLORYELLOW;
STICKLINE(ISLASTBAR=1 AND LJ<ZT,HT,LT,N*8,0),COLORBLUE;
STICKLINE(ISLASTBAR=1 AND LJ=ZT,HT,LT,N*8,0),COLORGRAY;
STICKLINE(ISLASTBAR=1 AND LJ>ZT,HT,LT,N*8,1),COLORWHITE;
STICKLINE(ISLASTBAR=1,ZT,ZT,N*8,0),COLORWHITE;
箱顶:HT,COLORWHITE,NODRAW;
箱底:LT,COLORWHITE,NODRAW;
箱中:ZT,COLORWHITE,NODRAW;
{XS2 }
N2:=102;
M:=7;
AA:=MA((2*CLOSE+HIGH+LOW)/4,5);
薛通A:AA*N2/100,COLORWHITE,DOTLINE;
薛通B:AA*(200-N2)/100,COLORWHITE,DOTLINE;
DRAWBAND(薛通A,RGB(120,80,60),薛通B,RGB(0,100,0));
DRAWKLINE(H,O,L,C);
DRAWTEXT_FIX(ISLASTBAR,0,0.92,0,'泊砂提示：1、日Ｋ线对降△边线的突破后并上穿箱中或者箱顶，如是上穿箱底要等第二天或第三天持续确认不再跌破趋势线，.'),COLORWHITE;
DRAWTEXT_FIX(ISLASTBAR,0,0.98,0,'2、视降△边和涨△边为三角形两边线，选三角形整理将结束的K图，DDX做多强烈,上攻成交量必须放大，各指标呈买点金叉时介入.'),COLORWHITE;
BT11:=MA(C,1);
持币:SMA(SMA(SMA(BT11,2,1),2,1),2,1),COLORCYAN,LINETHICK2;
SMA22:=MA(持币,3);
持股:IF(持币>SMA22,持币,DRAWNULL),COLORMAGENTA,LINETHICK2;
STICKLINE(持币,C,O ,1,0 ),COLORGREEN;
STICKLINE(C>持股,C,O ,1,0 ),COLORRED;
{短期支撑压力线}
N1:=5;
A1:=REF(H,N1)=HHV(H,2*N1+1);
B1:=FILTER(A1,N1);
C1:=BACKSET(B1,N1+1);
D1:=FILTER(C1,N1);
A2:=REF(L,N1)=LLV(L,2*N1+1);
B2:=FILTER(A2,N1);
C2:=BACKSET(B2,N1+1);
D2:=FILTER(C2,N1);
E1:=(REF(LLV(L,2*N1),1)+REF(HHV(H,2*N1),1))/2;
E2:=(H+L)/2;
H1:=(D1 AND NOT(D2 AND E1>=E2)) OR ISLASTBAR OR BARSCOUNT(C)=1;
L1:=(D2 AND NOT(D1 AND E1<E2));
H2:=D1 AND NOT(D2 AND E1>=E2);
X1:=REF(BARSLAST(H1),1)+1;
F1:=BACKSET(H1 AND COUNT(L1,X1)>0,LLVBARS(IF(L1,L,10000),X1));
G1:=F1>REF(F1,1);
I1:=BACKSET(G1,2);
LD:=I1>REF(I1,1);
L2:=LD OR ISLASTBAR OR BARSCOUNT(C)=1;
X2:=REF(BARSLAST(L2),1)+1;
F2:=BACKSET(L2 AND COUNT(H2,X2)>0,HHVBARS(IF(H2,H,0),X2));
G2:=F2>REF(F2,1);
I2:=BACKSET(G2,2);
HD:=I2>REF(I2,1);
R1:=BACKSET(ISLASTBAR,BARSLAST(HD)+1);
S1:=R1>REF(R1,1);
T1:=BACKSET(ISLASTBAR,BARSLAST(LD)+1);
U1:=T1>REF(T1,1);
R2:=BACKSET(S1,REF(BARSLAST(HD),1)+2);
S2:=R2>REF(R2,1);
T2:=BACKSET(U1,REF(BARSLAST(LD),1)+2);
U2:=T2>REF(T2,1);
短压力线:DRAWLINE(S2,H,S1,H,1),COLORGREEN;
短支撑线:DRAWLINE(U2,L,U1,L,1),COLORRED;
降△边:DRAWLINE(HIGH>=HHV(HIGH,10),HIGH,LOW<=LLV(LOW,3),HHV(HIGH,3),1),COLORCYAN,DOTLINE;
涨△边:DRAWLINE(LOW<=LLV(LOW,10),LOW,HIGH>=HHV(HIGH,3),LLV(LOW,3),1),COLORCYAN,DOTLINE;
{中期趋势回归划线 牛牛指标网提供 www.tdx001.com}
UR:=6;
LR:=UR;
TC1:=IF(H=HHV(H,8*UR),H,DRAWNULL);
TC2:=CONST(BARSLAST(TC1=H))+1;
UPPER:=CONST(IF(TC2=1,H,REF(H,TC2-1)));
BC1:=IF(L=LLV(L,8*LR),L,DRAWNULL);
BC2:=CONST(BARSLAST(BC1=L))+1;
LOWER:=CONST(IF(BC2=1,L,REF(L,BC2-1)));
LP:=CURRBARSCOUNT<=BC2 AND L=LOWER;{低点定位}
HP:=CURRBARSCOUNT<=TC2 AND H=UPPER;{高点定位}
STICKLINE(IF(BC2>TC2,HP,LP),LOWER,UPPER,0,0),COLOR628962;
STICKLINE(IF(BC2>TC2,LP,HP),LOWER,UPPER,0,0),COLOR628962;
NOD:=(IF(TC2>BC2,TC2,BC2)-IF(TC2>BC2,BC2,TC2));{用时}
LR1:=FORCAST(C,NOD+1);
NP:IF(CURRBARSCOUNT<=MAX(BC2,TC2),CONST(IF(MIN(TC2,BC2)=1,LR1,REF(LR1,MIN(TC2,BC2)-1))),DRAWNULL),POINTDOT,COLOR93BDA8;{近点}
LR2:=SLOPE(C,NOD+1);
LR3:=CONST(IF(MIN(TC2,BC2)=1,LR2,REF(LR2,MIN(TC2,BC2)-1)));
FP:NP-LR3*(NOD),POINTDOT,COLOR93BDA8;{远点}
EQU:(NP+FP)/2,POINTDOT,COLOR93BDA8;
AD:=ABS(NP-FP);{高差};
DBL:=BARSLAST(BC1!=DRAWNULL)+1;
DBH:=BARSLAST(TC1!=DRAWNULL)+1;
BSP:=IF(BC2>TC2,DBL,DBH)-1;
LRL:=IF(NP>FP,FP+AD/NOD*BSP,FP-AD/NOD*BSP);
AT1:=IF(BETWEEN(CURRBARSCOUNT,BC2,TC2) AND H>LRL,H,LRL);
AT2:=HHV(AT1-LRL,MAX(BC2,TC2));
AT3:=CONST(BARSLAST(AT1-LRL=AT2));
AT4:=CONST(IF(AT3=0,H,REF(H,AT3)));
AT5:=CONST(IF(AT3=0,AT1-LRL,REF(AT1-LRL,AT3)));
ATL:=LRL+AT5;
UT1:=IF(BETWEEN(CURRBARSCOUNT,BC2,TC2) AND L<LRL,L,LRL);
UT2:=HHV(LRL-UT1,MAX(BC2,TC2));
UT3:=CONST(BARSLAST(LRL-UT1=UT2));
UT4:=CONST(IF(UT3=0,H,REF(H,UT3)));
UT5:=CONST(IF(UT3=0,LRL-UT1,REF(LRL-UT1,UT3)));
UTL:=LRL-UT5;
RH:=IF(CURRBARSCOUNT>=MIN(BC2,TC2)-10,ATL,CONST(REF(ATL,MIN(BC2,TC2)-11)));{限制高}
RL:=IF(CURRBARSCOUNT>=MIN(BC2,TC2)-10,UTL,CONST(REF(UTL,MIN(BC2,TC2)-11)));{限制低}
中期中轨:IF(NP>FP,IF(LRL<=RH,LRL,DRAWNULL),IF(LRL>=RL,LRL,DRAWNULL)),COLOR628962;
中期上轨:IF(NP>FP,IF(ATL<=RH,ATL,DRAWNULL),IF(ATL>=RL,ATL,DRAWNULL)),COLOR628962;
中期下轨:IF(NP>FP,IF(UTL<=RH,UTL,DRAWNULL),IF(UTL>=RL,UTL,DRAWNULL)),COLOR628962;
2.选股公式
{突破线选股}
YLX:=DRAWLINE(HIGH>=HHV(HIGH,10),HIGH,LOW<=LLV(LOW,3),HHV(HIGH,3),1);
ZCX:=DRAWLINE(LOW<=LLV(LOW,10),LOW,HIGH>=HHV(HIGH,3),LLV(LOW,3),1);
XYL:=YLX<REF(YLX,1);
SZC:=ZCX>REF(ZCX,1);
QS:=MA(C,3)>MA(C,5);
{箱体}
N:=13;
BC:=(H*0.382+L*0.618+O*0.382+C*0.618)/2;
LJ:=IF(INDEXC=C,BC,(BC+AMOUNT/(V*100))/2),COLORGRAY;
HT:=REF((HHV(LJ,N*0.691)+HHV(LJ,N)+HHV(LJ,N*1.309))/3,1),LINETHICK,COLORRED;
LT:=REF((LLV(LJ,N*0.691)+LLV(LJ,N)+LLV(LJ,N*1.309))/3,1),LINETHICK,COLORGREEN;
ZT:=(HT+LT)/2,LINETHICK,COLORYELLOW;
XG:=(CROSS(C,HT) OR CROSS(C,LT) OR CROSS(C,ZT));
泊砂选股:CROSS(C,YLX)AND XYL AND SZC AND QS AND XG AND V>MA(V,5);
8411201.png
|
